Отличия SQL диалекта YQL от ANSI SQL

В данном разделе описываются различие SQL диалекта YQL и стандарта ISO/IEC 9075-2 (part 2: Foundation) в версии SQL-2011.
Сравнение делается по таблице №38 из стандарта
("Feature taxonomy and definition for mandatory features").

Отличия в поведении YQL от ANSI SQL

В данной таблице собраны сценарии когда один и тот же запрос по-разному работает в YQL и в ANSI SQL.

Статус поддержки ANSI SQL

E021 Character string types

Должны поддерживаться:

• CHARACTER[(len)] (он же CHAR)- строковой тип фиксированной длинны
• VAR CHAR[(len)] (он же CHARACTER VARYING) - строковой тип переменной длинны

Должен так же поддерживаться опциональный спецификатор CHARACTER SET cs и возможность задать правила сортировки с помощью COLLATE

В YQL эти типы не поддерживаются. Ближайшим аналогом является тип String,
который представляет собой бинарную строку переменной длинны.

E021-03 Character literals

По стандарту, строковой литерал имеет следующий вид

<character string literal> ::=
  [ <introducer> <character set specification> ]
      <quote> [ <character representation>... ] <quote>
      [ { <separator> <quote> [ <character representation>... ] <quote> }... ]
<separator> ::=
  { <comment> | <white space> }...
<introducer> ::=
  <underscore>
<character representation> ::=
    <nonquote character>
  | <quote symbol>
<quote symbol> ::=
  <quote> <quote>

В YQL:

• Не поддерживается экранирование через '
• Не поддерживается <character set specification>
• Не поддерживается неявная конкатенация литералов ('aaa' 'bbb' по стандарту означает то же что и 'aaabbb)

С другой стороны:

• Строковые литералы можно заключать в двойные кавычки "aaa"
• Работает C-style экранирование через бэкслеш
• Поддерживаются многострочные строковые литералы

E021-05 OCTET_LENGTH function

CHARACTER_LENGTH(<character value expression>) [USING CHARACTERS | OCTETS]
OCTET_LENGTH(<string value expression>)

В YQL поддерживается LENGTH(<string value expressiom>) которая возвращает длину строки в байтах

E021-06 SUBSTRING function

<character substring function> ::=
  SUBSTRING <left paren> <character value expression> FROM <start position>
      [ FOR <string length> ] [ USING CHARACTERS | OCTETS ] <right paren>

В YQL поддерживается в варианте SUBSTRING(str, start, len).
Нумерация символов в строке в YQL начинается с нуля

E021-09 TRIM function

 TRIM([[LEADING | TRAILING | BOTH] [<char value expression>] FROM] <char value expression>)

Удаления префикса/суффикса из строки. В YQL не поддерживается, функциональный эквивалент можно получить с использованием String/Unicode UDF

E021-11 POSITION function

POSITION(S1 IN S2) [USING CHARACTERS | OCTETS]

Поиск подстроки S1 в S2.

В YQL доступен в варианте FIND(S2, S1). Позиции нумеруются с 0, если строка не найдена, возвращается NULL.

E031 Identifiers

По стандарту, идентификаторы (например имена таблиц и колонок) могут являться
regular identifiers и delimited identifiers.
Regular identifiers начинаются с буквы и могут содержать только буквы, цифры и символы подчеркивания.

E031-01 Delimited identifiers

Delimited identifiers заключены в кавычки: "abc def" и могут содержать произвольные символы.
Кавычки экранируются двойными кавычками: "complex ""identifier"""

В YQL вместо кавычек используются бэктики

E051 Basic query specification

Общий вид SELECT запроса в стандарте такой

<query specification> ::=
  SELECT [ <set quantifier> ] <select list> <table expression>
<set quantifier> ::=
    DISTINCT
  | ALL
<select list> ::=
    <asterisk>
  | <select sublist> [ { <comma> <select sublist> }... ]
<select sublist> ::=
    <derived column>
  | <qualified asterisk>
<qualified asterisk> ::=
    <asterisked identifier chain> <period> <asterisk>
  | <all fields reference>
<asterisked identifier chain> ::=
  <asterisked identifier> [ { <period> <asterisked identifier> }... ]
<asterisked identifier> ::=
  <identifier>
<derived column> ::=
  <value expression> [ <as clause> ]
<as clause> ::=
  [ AS ] <column name>
<all fields reference> ::=
  <value expression primary> <period> <asterisk>
      [ AS <left paren> <all fields column name list> <right paren> ]
<all fields column name list> ::=
  <column name list>

<table expression> ::=
  <from clause>
      [ <where clause> ]
      [ <group by clause> ]
      [ <having clause> ]
      [ <window clause> ]
<from clause> ::=
  FROM <table reference list>
<table reference list> ::=
  <table reference> [ { <comma> <table reference> }... ]

В YQL не поддерживаются множественные таблицы после FROM (<table reference list> содержит более одного элемента)

E051-01 SELECT DISTINCT

SELECT DISTINCT поддерживается за исключением варианта с asterisk/qualified asterisk

E051-07 Qualified * in select list

В YQL:

• <asterisk identifier chain> может состоять только из одного элемента
• В <all fields reference> не поддерживаются алиасы <all fields column name list>
• <value expression primary> может содержать только ссылку на таблицу

E061-01 Comparison predicate

В YQL поддерживаются операторы <,>,=,<>,<=,>= для совместимых типов

E061-07 Quantified comparison predicate

<quantified comparison predicate> ::=
  <row value predicand> <quantified comparison predicate part 2>
<quantified comparison predicate part 2> ::=
  <comp op> <quantifier> <table subquery>
<quantifier> ::=
    <all>
  | <some>
<all> ::= ALL
<some> ::=
    SOME
  | ANY